Как работать с формулой ЕСЛИ в Excel и Google Таблицах

ЕСЛИ — функция в Excel и Google Таблицах. Она проверяет, выполняется ли заданное условие, и в зависимости от ответа «да» или «нет» — выводит нужное значение или выполняет расчет. С помощью этой формулы можно быстро проверить выполнение плана, рассчитать конверсии или автоматически отсортировать данные по категориям. Разбираем, как работает функция и как применять ее для автоматизации расчетов в отчетах и аналитике.

Синтаксис функции ЕСЛИ

В общем виде формула строится так: 

=ЕСЛИ(логическое_выражение; значение_если_истина; [значение_если_ложь])

Она состоит из компонентов:

• логическое_выражение — условие, которое проверяется. Результатом проверки всегда будет одно из двух логических значений: ИСТИНА или ЛОЖЬ;
• значение_если_истина — результат, который появится в ячейке, если условие выполняется;
• значение_если_ложь — результат, который появится, если условие не выполняется. Если этот аргумент опустить, то при ложном условии формула покажет значение ЛОЖЬ.

Например, при анализе продаж c помощью функции ЕСЛИ можно быстро проверить, достигнуты ли плановые показатели. Если продажи выполнены на 100%, то план считается выполненным. Формула будет выглядеть так:

=ЕСЛИ(B2=100; "План выполнен"; "План не выполнен")

Чтобы составить условие, используются логические операторы.

В русскоязычных версиях Excel и Google Таблиц аргументы функции разделяются точкой с запятой (;). В англоязычных версиях используется запятая (,). К примеру, так выглядит формула в русскоязычном интерфейсе:

=ЕСЛИ(A1>100; "Много"; "Мало")

А так в англоязычном интерфейсе:

=IF(A1>100, "High", "Low")

Если в формуле будет использован неправильный знак, то ячейка покажет сообщение об ошибке и не рассчитает результат.

Как использовать функцию ЕСЛИ

Функцию ЕСЛИ можно использовать в простых проверках и в сложных логических конструкциях с несколькими условиями. Разберем основные типы формул и примеры, где функция помогает автоматизировать расчеты и анализ.

Классическая формула с тремя аргументами

В этом варианте функция проверяет условие и выводит один из двух результатов. Такой формат используется чаще всего, когда нужно задать действие при выполнении условия и альтернативное значение, если условие не выполняется. Например, если продажи превысили 50 000 ₽, начислить премию 10% от суммы, иначе — 0. Формула выглядит так:

=ЕСЛИ(B2>50000; B2*0,1; 0)

Формула с двумя аргументами

Если третий аргумент — «значение_если_ложь» — не указан, функция при невыполненном условии покажет значение ЛОЖЬ. Например, в таблице нужно выделить задачи, которые не выполнены в срок. Если в столбце C у задачи стоит статус «Просрочена», нужно вывести в ячейке заметное предупреждение «СРОЧНО!». Если статус другой, ничего выводить не нужно:

=ЕСЛИ(C2="Просрочена"; "СРОЧНО!")

Если условие не выполнится — например, статус задачи будет «В работе», ячейка покажет значение ЛОЖЬ. Чтобы эта надпись не отвлекала, лучше добавить вместо третьего аргумента кавычки:

=ЕСЛИ(C2="Просрочена"; "СРОЧНО!";"")

Это означает, что при невыполненном условии ячейка будет пустой — таблица будет выглядеть визуально чище.

Несколько условий: И, ИЛИ, вложенные ЕСЛИ и ЕСЛИМН

Иногда для принятия решения нужно проверить не одно, а несколько условий. Для этого ЕСЛИ комбинируют с функциями И и ИЛИ.

ЕСЛИ с оператором И. Функция И проверяет несколько условий и показывает значение ИСТИНА, только если все они выполнены. Например, нужно присвоить кандидату статус «Подходит», если его опыт работы больше 3 лет и он знает английский. Если хотя бы одно условие не выполняется, кандидат «Не подходит». Формула:

=ЕСЛИ(И(D2>3; E2="Да"); "Подходит"; "Не подходит")

ЕСЛИ с оператором ИЛИ. Проверяет, выполнено ли хотя бы одно из перечисленных условий. Например, нужно предоставить клиенту скидку, если сумма его заказа превышает 10 000 ₽ или у него VIP-статус. Формула для проверки:

=ЕСЛИ(ИЛИ(F2>10000; G2="VIP"); "Скидка 15%"; "Нет скидки")

Функция ЕСЛИМН. Она есть в новых версиях Excel от 2019 года и в Google Таблицах. Функция позволяет создавать цепочки проверок. Например, выставить оценку по результатам теста: «Отлично», если результат выше 90 баллов, «Хорошо» — в диапазоне 75-89 баллов или «Удовлетворительно» — меньше 75 баллов:

=ЕСЛИМН(H2>=90; "Отлично"; H2>=75; "Хорошо"; H2<75; "Удовлетворительно")

Вложенные ЕСЛИ. Это старый способ последовательной проверки нескольких условий — сейчас вместо него используют функцию ЕСЛИМН. Формула выполняет проверки по цепочке: если выполняется первое условие, выводится один результат; если нет — проверяется следующее. Например, нужно поставить оценку за выполнение теста. Если значение в ячейке H2 выше 90 баллов — результат «Отлично», от 75 до 89 — «Хорошо», ниже 75 — «Удовлетворительно»:

=ЕСЛИ(H2>=90; "Отлично"; ЕСЛИ(H2>=75; "Хорошо"; "Удовлетворительно"))

Так работает цепочка вложенных ЕСЛИ, каждое следующее условие проверяется, только если предыдущее не выполнено.

Метод подходит для простых таблиц, но если данных много — такая функция замедляет расчеты. Поэтому для сложных отчетов лучше использовать ЕСЛИМН — она быстрее анализирует несколько условий.

ЕСЛИ в сочетании с другими функциями

ЕСЛИ можно комбинировать с другими функциями Excel и Google Таблиц, чтобы расширить возможности формул. Например, добавить проверку на ошибки или автоматически подставлять недостающие данные.

ЕСЛИОШИБКА и ВПР. Функция ВПР ищет данные в одной таблице и подставляет найденные значения в другую. Если нужное значение отсутствует, появляется ошибка #Н/Д, которая портит внешний вид отчета.

Вместо этого можно использовать формулу ЕСЛИОШИБКА. Она проверяет результат и подставляет заданный текст, если функция не нашла нужные данные.

Например, в отчете нужно указать стоимость клика для каждого рекламного канала. Данные о об этом указаны в отдельной таблице на соседнем листе. Если нужное значение не найдено, появится надпись «Нет данных» вместо ошибки #Н/Д.

=ЕСЛИОШИБКА(ВПР(A2; Каналы!A:B; 2; 0); "Нет данных")

Из чего состоит формула:

• A2 — значение, которое нужно найти. В конкретном примере это название рекламного канала в ячейке A2.
• Каналы!A:B — диапазон, где выполняется поиск. Здесь указаны два столбца на листе «Каналы»: в первом находятся названия каналов, во втором — средняя стоимость клика.
• 2 — номер столбца в указанном диапазоне, из которого берется результат.
• 0 — тип поиска. Ноль означает точное совпадение. Если поставить 1 или ИСТИНА, то функция ВПР будет искать приблизительные совпадения — это может привести к ошибкам.
• "Нет данных" — сообщение, которое показывает функция ЕСЛИОШИБКА, если поиск не дал результата.

Формула ЕСЛИОШИБКА ищет название канала из столбца A на листе «Каналы». Если совпадение найдено — подставляет его стоимость клика. Это ускоряет поиск данных.

ЕСЛИ и СЧЕТЕСЛИ. Помогает проверять наличие элемента в списке — например, есть ли email в «черном списке»:

=ЕСЛИ(A2=""; ""; ЕСЛИ(СЧЕТЕСЛИ('Черный список'!$A$2:$A$10; A2)>0; "Заблокирован"; "OK"))

Функция СЧЕТЕСЛИ проверяет, сколько раз значение из ячейки A2 встречается в листе «Черный список». Если результат больше нуля — значит, совпадение найдено, и ЕСЛИ выводит «Заблокирован». Если нет — отображается «OK».

Отличие ЕСЛИ в Excel и Google Таблицах

Функции ЕСЛИ, И, ИЛИ и ЕСЛИМН используют в Excel и Google Таблицах одинаковый синтаксис. Различие в том, как они обрабатывают диапазоны. Допустим, нужно проверить, выполнен ли план продаж по каждому менеджеру. В столбце A указаны продажи, а в столбце B нужно автоматически вывести результат: «План выполнен», если сумма больше 10 000, и «План не выполнен» — если меньше.

Для проверки можно использовать формулу:

=ЕСЛИ(A2>10000; "План выполнен"; "План не выполнен")

В Excel формула рассчитывает результат только для одной строки. Чтобы применить ее к остальным, нужно скопировать или протянуть вниз по столбцу.

В Google Таблицах можно сделать то же самое, но если добавить функцию ARRAYFORMULA, результат заполнится сразу по всему диапазону:

=ARRAYFORMULA(ЕСЛИ(A2:A5>10000; "План выполнен"; "План не выполнен"))

Это удобно при работе с отчетами, динамическими таблицами, где данные постоянно обновляются и нужно, чтобы расчеты выполнялись автоматически.

Типичные ошибки при работе с функцией ЕСЛИ и их решение